Creating ColdFusion’s missing ‘instanceof’ method

Yesterday I was going back over some ColdSpring code, implementing some new features, and I came across the answer (sort of) to a question I remember being discussed a while back on CVCDev or topica. How do you find out if an object is an instance of a particular cfc or one of it’s subclasses? Unfortunately, ColdFusion doesn’t have the keyword ‘instanceof’ like Java and C#, which I suppose is far more commonly used in a strongly typed language. Why would it be more necessary? Well, for one thing the O’Reilly C# book I have advocates the use of instanceof before casting, alleviating ClassCastExceptions, but that’s another story. Anyway, I have run into a few situations in ColdFusion where I really need this functionality. So how do we do this in CF? Well, when I looked at what I had written a few months ago, although it works ok, the comment below it, ‘shouldn’t I be looking in the ‘extends’ key only?’, basically pointed out that it was a shotty implementation at best (btw, I looked back over the history of the file, and the original comment was ‘this sucks, I need to do this better later!’), so I asked Sean what he thought about it. Here’s something along the line of the original code I sent him, the main problem here being that by using StructFind() I am searching every key in every nested struct:

<cffunction name="isInstanceOf" access="public" returntype="Boolean" output="false">
  <cfargument name="obj" type="any" required="true"/>
  <cfargument name="reqType" type="string" required="true" />
  <cfif ArrayLen(StructFindValue(getMetaData(obj), reqType, "ALL"))>
    <cfreturn true />
  <cfelse>
    <cfreturn false />
  </cfif>
</cffunction>

Sean immediately pointed out that that was ok, but slow. Maybe I should search recursively through the extends keys of the metadata. So here’s what I ended up with, which seems a heck of a lot tighter to me. I shied away from the recursive method call, because that seemed it would be putting a little extra overhead on the search, but this implementation seams nice to me, thank for the input Sean!

<cffunction name="isInstanceOf" access="public" returntype="Boolean" output="false">
  <cfargument name="obj" type="any" required="true"/>
  <cfargument name="reqType" type="string" required="true" />
  <cfset var searchMd = getMetaData(obj) />
  <cfif searchMd.name IS reqType >
    <cfreturn true />
  <cfelse>
    <cfloop condition="#StructKeyExists(searchMd, "extends")#">
       <cfset searchMd = searchMd.extends />
       <cfif searchMd.name IS reqType>
         <cfreturn true />
       </cfif>
    </cfloop>
  </cfif>
  <cfreturn false />
</cffunction>